# Build extlibs as shared libraries
set(BUILD_SHARED_LIBS_SAVED "${BUILD_SHARED_LIBS}")
set(BUILD_SHARED_LIBS ON)

# Set CMAKE_POLICY_DEFAULT_CMP0077 to NEW to make option() command in cfitsio
# CMakeLists.txt honoring the BUILD_SHARED_LIBS variable
set(CMAKE_POLICY_DEFAULT_CMP0077 NEW)


add_subdirectory(cfitsio)
add_subdirectory(ape)
add_subdirectory(atFunctions)
add_subdirectory(fftw)
add_subdirectory(heainit)
add_subdirectory(heaio)
add_subdirectory(heasp)
add_subdirectory(heautils)


### wcslib ###
# TODO: 'make clean' for wcslib
if (CMAKE_SYSTEM_NAME STREQUAL "Linux")
    set (WCSLIB_BUILD make && ln -fs libwcs_simput-7.7.so C/libwcs_simput.so)
else ()
    set (WCSLIB_BUILD make)
endif()

ExternalProject_Add(
    wcslib_simput
    SOURCE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/wcslib/
    CONFIGURE_COMMAND cd ${CMAKE_CURRENT_SOURCE_DIR}/wcslib && autoreconf -vi && ./configure --prefix=${CMAKE_INSTALL_PREFIX} --libdir=${CMAKE_INSTALL_FULL_LIBDIR}
    BUILD_IN_SOURCE 1
    BUILD_COMMAND ${WCSLIB_BUILD}
    INSTALL_COMMAND make install
)

install(SCRIPT "${CMAKE_CURRENT_SOURCE_DIR}/post_install_script.cmake")

# Reset BUILD_SHARED_LIBS
set(BUILD_SHARED_LIBS "${BUILD_SHARED_LIBS_SAVED}")
